home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib05.dsk / APPLE BIORHYTHMS.bas < prev    next >
BASIC Source File  |  2023-02-26  |  15KB  |  339 lines
  1. 1  REM ********************************
  2. 2  REM **    APPLE BIORHYTHMS        **
  3. 3  REM **   BY P.J. VORENBERG        **
  4. 4  REM **  COPYRIGHT (C) 1980 BY     **
  5. 5  REM **    MICRO-SPARC, INC.       **
  6. 6  REM **   LINCOLN, MA. 01773       **
  7. 7  REM ********************************
  8. 9  REM  << REQUIRES APPLE II OR APPLE II PLUS WITH APPLESOFT IN ROM.  PRINTER IS OPTIONAL >>  IMAGEWRITER VERSION
  9. 13 SCL = 50:PA = 0
  10. 14  HOME : HTAB 12: INVERSE : PRINT "BIORHYTHM PROGRAM": NORMAL : PRINT : HTAB 12: PRINT "BY P.J. VORENBERG": PRINT : HTAB 10: PRINT "COPYRIGHT (C) 1981 BY": PRINT : HTAB 12: PRINT "MICRO-SPARC, INC.": PRINT : HTAB 11: PRINT "LINCOLN, MA. 01773"
  11. 15  NORMAL 
  12. 20  RESTORE : READ NB: FOR I = 1 TO NB: READ NM$(I),DT$(I): NEXT 
  13. 30  DIM MTH$(12): FOR I = 1 TO 12: READ MTH$(I): NEXT 
  14. 32  DIM DAYS(12): FOR I = 1 TO 12: READ DAYS(I): NEXT 
  15. 33  DIM XX(40)
  16. 35 LN = 40
  17. 37 YN$ = "N"
  18. 39 GF = 0: IF  LEFT$(YN$,1) = "N"  THEN  GOSUB 600:GF = 1
  19. 40  DIM EC(LN),MC(LN),PC(LN)
  20. 90  PRINT 
  21. 100  HOME : INVERSE : INPUT "WHO ARE YOU? ";NM$: NORMAL 
  22. 110  FOR I = 1 TO NB: IF NM$ = NM$(I)  THEN DT$ = DT$(I):I = NB: GOTO 125
  23. 115  NEXT : PRINT 
  24. 120  INVERSE : PRINT "WHEN WERE YOU BORN";: NORMAL : INPUT " (NO COMMAS PLEASE)? ";DT$
  25. 122  IF  LEN(DT$) = 0  THEN 120
  26. 125  IF PA  OR (GF  AND FL)  THEN 135
  27. 130  PRINT : INVERSE : INPUT "WHAT YEAR IS IT NOW? ";YR$: NORMAL 
  28. 132 TD$ = TD$ +"/" +YR$
  29. 135  GOSUB 1000: REM  CONVERT DATE
  30. 140 BDY = DY:BMTH = MTH:BYR = YR
  31. 150 BRN$ = DT$:DT$ = TD$: GOSUB 1000
  32. 160 TDY = DY:TMTH = MTH:TYR = YR
  33. 170  GOSUB 2000
  34. 200  GOSUB 3000: REM  CALCULATE CYCLES
  35. 210  IF   NOT GF  THEN  GOSUB 4000: GOTO 300
  36. 250  PRINT : INVERSE : INPUT "PRINTER, SCREEN, OR BOTH? ";CH$: NORMAL 
  37. 260 A$ =  LEFT$(CH$,1): IF A$ = "P"  OR A$ = "B"  THEN  GOSUB 5000
  38. 270  IF A$ = "S"  OR A$ = "B"  THEN  GOSUB 4000
  39. 300  HOME : INVERSE : INPUT "WHO'S NEXT? ";NM$: NORMAL 
  40. 310  IF NM$ = ""  THEN 400
  41. 320  IF GF  THEN  GOSUB 600
  42. 325 PA = 1
  43. 330  GOTO 110
  44. 400  END 
  45. 599 :
  46. 600  REM  QUESTIONS
  47. 601 :
  48. 605 FL = 0
  49. 607  PRINT : PRINT "IF YOU DON'T WANT TO DECIDE THE NEXT": PRINT "QUESTIONS, ANSWER WITH 'RETURN'."
  50. 610  PRINT : INPUT "DO YOU WANT A DESCRIPTION OF BIORHYTHMS?";YN$: IF  LEFT$(YN$,1) = "Y"  THEN  GOSUB 6998
  51. 615  PRINT 
  52. 620  INPUT "HOW LONG IN DAYS DO YOU WANT YOUR CHART? ";LM$
  53. 625  IF LM$ = ""  THEN 635
  54. 627 LM =  VAL(LM$)
  55. 630  IF LM < >0  THEN LN = LM
  56. 632  PRINT "**************************************"
  57. 633  PRINT : PRINT "FORMAT FOR DATES:  DAY MONTH.NAME YEAR": PRINT : INVERSE : PRINT "  EXAMPLE :";: NORMAL : PRINT "  1 MAY 1981": PRINT 
  58. 634  PRINT "**************************************"
  59. 635  PRINT 
  60. 640  INPUT "WHAT DATE DO YOU WANT THE CHART TO START ON? ";ST$
  61. 645  IF ST$ = ""  THEN 640
  62. 650  IF ST$ < >""  THEN TD$ = ST$:FL = 1
  63. 660  PRINT 
  64. 700  RETURN 
  65. 999 :
  66. 1000  REM  CONVERT DATE
  67. 1001 :
  68. 1002  IF  LEN(DT$) = 0  THEN  PRINT "ERROR!! NO DATE GIVEN.": STOP 
  69. 1005  REM  WHICH KIND?
  70. 1010  FOR J = 1 TO  LEN(DT$)
  71. 1020  IF  MID$ (DT$,J,1) = "/"  THEN J = 1000: GOTO 1500
  72. 1030  NEXT 
  73. 1040 A$ =  LEFT$(DT$,1): IF A$ > = "A"  AND A$ < = "Z"  THEN 1200
  74. 1041 :
  75. 1042  REM  DAY FIRST
  76. 1043 :
  77. 1045 PL = 1
  78. 1050  IF  MID$ (DT$,PL,1) > = "0"  AND  MID$ (DT$,PL,1) < = "9"  THEN PL = PL +1: GOTO 1050
  79. 1060 DY =  VAL( MID$ (DT$,1,PL -1))
  80. 1070 ST = PL
  81. 1080  IF  MID$ (DT$,PL,1) > = "A"  AND  MID$ (DT$,PL,1) < = "Z"  THEN PL = PL +1: GOTO 1080
  82. 1090  IF ST = PL  THEN PL = PL +1:ST = PL: IF ST < =  LEN(DT$)  THEN 1080
  83. 1100 MTH$ =  MID$ (DT$,ST,PL -ST): GOSUB 1800
  84. 1110 ST = PL
  85. 1120  IF  MID$ (DT$,PL,1) > = "0"  AND  MID$ (DT$,PL,1) < = "9"  THEN PL = PL +1: GOTO 1120
  86. 1130  IF ST = PL  THEN PL = PL +1:ST = PL: IF ST < =  LEN(DT$)  THEN 1120
  87. 1140 YR =  VAL( MID$ (DT$,ST,PL -ST))
  88. 1145  IF YR <1500  THEN YR = YR +1900
  89. 1150  RETURN 
  90. 1199 :
  91. 1200  REM  MONTH FIRST
  92. 1201 :
  93. 1210 PL = 1
  94. 1220  IF  MID$ (DT$,PL,1) > = "A"  AND  MID$ (DT$,PL,1) < = "Z"  THEN PL = PL +1: GOTO 1220
  95. 1230 MTH$ =  MID$ (DT$,1,PL -1): GOSUB 1800
  96. 1240 ST = PL
  97. 1250  IF  MID$ (DT$,PL,1) > = "0"  AND  MID$ (DT$,PL,1) < = "9"  THEN PL = PL +1: GOTO 1250
  98. 1260  IF ST = PL  THEN PL = PL +1:ST = PL: IF ST < =  LEN(DT$)  THEN 1250
  99. 1270 DY =  VAL( MID$ (DT$,ST,PL -ST)): IF DY >31  THEN  PRINT  CHR$(4)"RUN"
  100. 1280 ST = PL
  101. 1290  IF  MID$ (DT$,PL,1) > = "0"  AND  MID$ (DT$,PL,1) < = "9"  THEN PL = PL +1: GOTO 1290
  102. 1300  IF ST = PL  THEN PL = PL +1:ST = PL: IF ST < =  LEN(DT$)  THEN 1290
  103. 1310 YR =  VAL( MID$ (DT$,ST,PL -ST)): IF YR <1500  THEN YR = YR +1900
  104. 1320  RETURN 
  105. 1499 :
  106. 1500  REM  SLASH SEPARATORS
  107. 1501 :
  108. 1510 PL = 1
  109. 1520  IF  MID$ (DT$,PL,1) < >"/"  THEN PL = PL +1: GOTO 1520
  110. 1530 MTH =  VAL( MID$ (DT$,1,PL -1)):PL = PL +1
  111. 1540 ST = PL
  112. 1550  IF  MID$ (DT$,PL,1) < >"/"  THEN PL = PL +1: GOTO 1550
  113. 1560 DY =  VAL( MID$ (DT$,ST,PL -ST)):PL = PL +1
  114. 1570 YR =  VAL( RIGHT$(DT$, LEN(DT$) -PL +1))
  115. 1580  IF YR <1500  THEN YR = YR +1900
  116. 1590  RETURN 
  117. 1799 :
  118. 1800  REM  DECODE MONTH
  119. 1801 :
  120. 1805 A =  LEN(MTH$)
  121. 1810  FOR J = 1 TO 12
  122. 1820  IF  LEFT$(MTH$(J),A) = MTH$  THEN MTH = J:J = 12: RETURN 
  123. 1830  NEXT 
  124. 1840  PRINT "NO MONTH FOUND": STOP 
  125. 1999 :
  126. 2000  REM  COMPUTE AGE IN DAYS
  127. 2001 :
  128. 2010 AGE = TYR -BYR
  129. 2020  IF BMTH <TMTH  THEN 2100
  130. 2030  IF BMTH >TMTH  THEN AGE = AGE -1: GOTO 2100
  131. 2050  IF BDY < = TDY  THEN 2100
  132. 2060 AGE = AGE -1
  133. 2100 AGE = AGE *365
  134. 2110 LEAP = 0
  135. 2120 ST =  INT(BYR/4) *4: IF ST < >BYR  THEN ST = ST +4
  136. 2125  IF ST >TYR  THEN 2160
  137. 2130  FOR J = ST TO TYR  STEP 4
  138. 2140  IF J < >1900  THEN LEAP = LEAP +1
  139. 2150  NEXT 
  140. 2160  IF ST < >BYR  THEN 2200
  141. 2170  IF BMTH >2  THEN LEAP = LEAP -1
  142. 2180  IF BDY = 29  AND BMTH = 2  THEN LEAP = LEAP -1
  143. 2200 ST =  INT(TYR/4) *4: IF ST < >TYR  THEN 2250
  144. 2210  IF TMTH >2  THEN 2250
  145. 2220 LEAP = LEAP -1
  146. 2250 AGE = AGE +LEAP
  147. 2255  IF BMTH = TMTH  THEN  IF BDY < = TDY  THEN AGE = AGE +TDY -BDY: RETURN 
  148. 2260 AGE = AGE +DAYS(BMTH) -BDY
  149. 2265  IF BMTH +1 = TMTH  THEN AGE = AGE +TDY: RETURN 
  150. 2270  IF BMTH = 12  THEN 2400
  151. 2275 FIN = 12: IF TMTH >BMTH  THEN FIN = TMTH -1
  152. 2280  FOR J = BMTH +1 TO FIN
  153. 2290 AGE = AGE +DAYS(J): NEXT 
  154. 2300  IF TMTH >BMTH  THEN AGE = AGE +TDY: RETURN 
  155. 2400  IF TMTH = 1  THEN AGE = AGE +TDY: RETURN 
  156. 2410  FOR J = 1 TO TMTH -1:AGE = AGE +DAYS(J): NEXT 
  157. 2420 AGE = AGE +TDY: RETURN 
  158. 2999 :
  159. 3000  REM  CYCLES
  160. 3001 :
  161. 3005 PI2 = 2 *3.14159265
  162. 3010  FOR J = 1 TO LN
  163. 3020 JA = AGE +J -1
  164. 3030 PC(J) = JA - INT(JA/23) *23
  165. 3040 PC(J) =  SIN(PC(J) *PI2/23) *SCL +SCL
  166. 3050 EC(J) = JA - INT(JA/28) *28
  167. 3060 EC(J) =  SIN(EC(J) *PI2/28) *SCL +SCL
  168. 3070 MC(J) = JA - INT(JA/33) *33
  169. 3080 MC(J) =  SIN(MC(J) *PI2/33) *SCL +SCL
  170. 3090 PC(J) =  INT(PC(J) +.5)
  171. 3100 EC(J) =  INT(EC(J) +.5)
  172. 3110 MC(J) =  INT(MC(J) +.5)
  173. 3120  NEXT 
  174. 3130  RETURN 
  175. 3999 :
  176. 4000  REM  SCREEN GRAPHICS
  177. 4001 :
  178. 4005 SQ = 40/101
  179. 4007 LM = 40: IF LN <40  THEN LM = LN
  180. 4010  FOR I = 1 TO LM:EC(I) = 39 - INT(EC(I) *SQ):MC(I) = 39 - INT(MC(I) *SQ):PC(I) = 39 - INT(PC(I) *SQ)
  181. 4020 XX(I) = I -1: NEXT 
  182. 4030  GR : COLOR= 15: HLIN 0,39 AT 19
  183. 4040  COLOR= 13
  184. 4050  FOR I = 1 TO LM: PLOT XX(I),EC(I): NEXT 
  185. 4060  COLOR= 14
  186. 4070  FOR I = 1 TO LM: PLOT XX(I),MC(I): NEXT 
  187. 4080  COLOR= 11
  188. 4090  FOR I = 1 TO LM: PLOT XX(I),PC(I): NEXT 
  189. 4100  HOME 
  190. 4110 DP = TDY:MP = TMTH:YP = TYR -1900:XX(1) = DP: GOSUB 6000
  191. 4120  FOR I = 2 TO LM
  192. 4130 XX(I) = DP: GOSUB 6000: NEXT 
  193. 4135  VTAB 21
  194. 4140  FOR I = 1 TO LM
  195. 4145 A$ = ""
  196. 4150 XX$ =  STR$(XX(I)): IF  LEN(XX$) = 2  THEN A$ =  LEFT$(XX$,1)
  197. 4160  IF  LEN(XX$) = 1  THEN A$ = XX$
  198. 4170  IF A$ = ""  THEN A$ = " "
  199. 4180  PRINT A$;: NEXT : IF LM <40  THEN  PRINT 
  200. 4190  FOR I = 1 TO LM
  201. 4195 A$ = " "
  202. 4200 XX$ =  STR$(XX(I)): IF  LEN(XX$) = 2  THEN A$ =  RIGHT$(XX$,1)
  203. 4210  PRINT A$;: NEXT : IF LM <40  THEN  PRINT 
  204. 4215  PRINT  TAB( 17)"DATES"
  205. 4220  PRINT "EMOTNL=YEL, MENTAL=AQUA, PHYSCL=PINK"; TAB( 39);: INPUT " ";YN$
  206. 4230  TEXT : HOME : RETURN 
  207. 4997 :
  208. 4998  REM  PRINT CYCLES
  209. 4999 :
  210. 5000 DP = TDY:MP = TMTH:YP = TYR
  211. 5006  PRINT  CHR$(4);"PR#1": PRINT  CHR$(27); CHR$(81): PRINT  CHR$(9)"132N": REM  IMAGEWRITER CODES
  212. 5007  PRINT  SPC( 41)"B I O R H Y T H M I C  C Y C L E S"
  213. 5008  PRINT : PRINT : PRINT  SPC( 56 - LEN(NM$)/2)"FOR "NM$
  214. 5009  PRINT : PRINT : PRINT  SPC( 41)"E = EMOTIONAL CYCLE (28 DAYS)"
  215. 5010  PRINT  SPC( 41)"M = MENTAL CYCLE    (33 DAYS)"
  216. 5011  PRINT  SPC( 41)"P = PHYSICAL CYCLE  (23 DAYS)"
  217. 5012  PRINT : PRINT : PRINT 
  218. 5013  PRINT  TAB( 13)"NEGATIVE" SPC( 84)"POSITIVE"
  219. 5015  FOR I = 1 TO LN
  220. 5020 CEC$ = "E"
  221. 5030 CMC$ = "M"
  222. 5040 CPC$ = "P"
  223. 5050  IF EC(I) < >MC(I)  THEN  GOTO 5070
  224. 5060 CEC$ = "D":CMC$ = "D"
  225. 5070  IF EC(I) < >PC(I)  THEN  GOTO 5090
  226. 5080 CEC$ = "D":CPC$ = "D"
  227. 5090  IF MC(I) < >PC(I)  THEN  GOTO 5110
  228. 5100 CMC$ = "D":CPC$ = "D"
  229. 5110  IF I < >1  THEN  GOSUB 6000
  230. 5125  GOSUB 6100
  231. 5130  NEXT I
  232. 5140  PRINT  CHR$(27); CHR$(80): PRINT  CHR$(4);" PR# 0"
  233. 5150  RETURN 
  234. 5990 :
  235. 5995  REM  GET NEXT DAY
  236. 5996 :
  237. 6000 DP = DP +1
  238. 6010  IF MP = 2  AND  INT(YP/4) *4 = YP  THEN 6040
  239. 6020  IF DP >DAYS(MP)  THEN 6050
  240. 6030  RETURN 
  241. 6040  IF DP < = 29  THEN  RETURN 
  242. 6050 DP = 1:MP = MP +1: IF MP >12  THEN MP = 1:YP = YP +1
  243. 6060  RETURN 
  244. 6090 :
  245. 6095  REM  ORDER VALUES
  246. 6096 :
  247. 6100 V1 = EC(I):V2 = MC(I):I1$ = CEC$:I2$ = CMC$
  248. 6110  IF (MC(I) <EC(I))  THEN V1 = MC(I):V2 = EC(I):I1$ = CMC$:I2$ = CEC$
  249. 6120  IF (PC(I) <V1)  THEN V3 = V2:I3$ = I2$:V2 = V1:I2$ = I1$:V1 = PC(I):I1$ = CPC$: GOTO 6140
  250. 6130  IF (PC(I) <V2)  THEN V3 = V2:I3$ = I2$:V2 = PC(I):I2$ = CPC$: GOTO 6140
  251. 6135 V3 = PC(I):I3$ = CPC$
  252. 6140  IF (50 <V1)  THEN V4 = V3:I4$ = I3$:V3 = V2:I3$ = I2$:V2 = V1:I2$ = I1$:V1 = 50:I1$ = "!": GOSUB 6300: GOTO 6180
  253. 6150  IF (50 <V2)  THEN V4 = V3:I4$ = I3$:V3 = V2:I3$ = I2$:V2 = 50:I2$ = "!": GOSUB 6320: GOTO 6180
  254. 6160  IF (50 <V3)  THEN V4 = V3:I4$ = I3$:V3 = 50:I3$ = "!": GOSUB 6340: GOTO 6180
  255. 6165 V4 = 50:I4$ = "!": GOSUB 6360
  256. 6170 :
  257. 6171  REM  COMPUTE SPACING
  258. 6172 :
  259. 6180 D2 = V2 -V1 -1
  260. 6190 D3 = V3 -V2 -1
  261. 6200 D4 = V4 -V3 -1
  262. 6210  IF D2 =  -1  THEN D2 = 0:I2$ = ""
  263. 6220  IF D3 =  -1  THEN D3 = 0:I3$ = ""
  264. 6230  IF D4 =  -1  THEN D4 = 0:I4$ = ""
  265. 6235 P$ =  STR$(DP):Q$ =  STR$(MP):R$ =  STR$(YP)
  266. 6237  PRINT  TAB( 3 - LEN(P$))P$;: PRINT  TAB( 6 - LEN(Q$))Q$;: PRINT  TAB( 8)R$;
  267. 6240  PRINT  TAB( 13) SPC( V1)I1$;: PRINT  SPC( D2)I2$;: PRINT  SPC( D3)I3$;: PRINT  SPC( D4)I4$: RETURN 
  268. 6295 :
  269. 6296  REM  REDUCE COMMON VALUES
  270. 6300  IF V1 = V2  THEN I1$ = I2$
  271. 6310  RETURN 
  272. 6320  IF V1 = V2  THEN I2$ = I1$
  273. 6325  IF V2 = V3  THEN I2$ = I3$
  274. 6330  RETURN 
  275. 6340  IF V3 = V2  THEN I3$ = I2$
  276. 6345  IF V3 = V4  THEN I3$ = I4$
  277. 6350  RETURN 
  278. 6360  IF V4 = V3  THEN I4$ = I3$
  279. 6370  RETURN 
  280. 6995 :
  281. 6996  REM  PRINT EXPLANATION
  282. 6997 :
  283. 6998 PZ = 0:ZP = 13:ZR = 4
  284. 6999  PRINT : INPUT "DO YOU WANT IT ON THE PRINTER? ";YN$: IF  LEFT$(YN$,1) = "Y"  THEN PZ = 1: PRINT  CHR$(4)"PR#1": PRINT  CHR$(17):ZP = 0:ZR = 0
  285. 7000  HOME : PRINT : PRINT "BIORHYTHM THEORY OFFERS AN EXPLANATION " CHR$(ZP)"OF PHYSICAL, MENTAL, AND EMOTIONAL"
  286. 7001  PRINT "FLUCTUATIONS!  PAST OBSERVATIONS HAVE " CHR$(ZP)"SHOWN BIOCHEMICAL AND PHYSIOLOGICAL"
  287. 7002  PRINT "FUNCTIONS FLUCTUATED BASED ON THE TIME " CHR$(ZP)"OF DAY, MONTH, YEAR OR SEASON.  IN"
  288. 7003  PRINT "1897, PHYSICIANS OBSERVED 'NATURAL " CHR$(ZP)"CYCLES' RELATED TO OCCURRENCE OF"
  289. 7004  PRINT "DISEASE.  SCIENTISTS HAVE DETERMINED " CHR$(ZP)"THREE BASIC CYCLES:"
  290. 7005  PRINT : PRINT  TAB( 5)"THE 'PHYSICAL' CYCLE IS 23 DAYS " CHR$(ZP) SPC( ZR)"LONG. IT RELATES TO A PERSON'S EN-"
  291. 7006  PRINT  TAB( 5)"DURANCE, STRENGTH, STAMINA, ENERGY," CHR$(ZP) SPC( ZR)"RESISTANCE, AND FEELING OF PHYSICAL"
  292. 7007  PRINT  TAB( 5)"CONFIDENCE AND WELL BEING."
  293. 7008  PRINT : PRINT  TAB( 5)"THE 'EMOTIONAL' CYCLE IS 28 DAYS " CHR$(ZP) SPC( ZR)"IN LENGTH AND RELATES TO A PERSON'S"
  294. 7009  PRINT  TAB( 5)"SENSITIVITY, REACTION TO STRESS, " CHR$(ZP) SPC( ZR)"EMOTIONAL STABILITY, AND ATTITUDE.": IF   NOT PZ  THEN  PRINT : INPUT "CONTINUE";YN$: HOME 
  295. 7010  PRINT : PRINT  TAB( 5)"THE THIRD CYCLE IS CALLED THE " CHR$(ZP) SPC( ZR)"'INTELLECTUAL' CYCLE WHICH LASTS"
  296. 7011  PRINT  TAB( 5)"FOR 33 DAYS.  THIS CYCLE RELATES " CHR$(ZP) SPC( ZR)"TO A PERSON'S LEARNING, DECISION"
  297. 7012  PRINT  TAB( 5)"MAKING, PERCEPTION, AND OTHER " CHR$(ZP) SPC( ZR)"MENTAL QUALITIES."
  298. 7013  PRINT : PRINT "BECAUSE THESE CYCLES ALWAYS RECUR, THE " CHR$(ZP)"POSITION OF EACH CHARACTERISTIC AT A"
  299. 7014  PRINT "FUTURE POINT IN TIME CAN BE FORECAST. " CHR$(ZP)"GENERALLY, THE EMOTIONAL AND PHYSICAL"
  300. 7015  PRINT "CYCLES ARE MORE SIGNIFICANT IN TERMS " CHR$(ZP)"OF EFFECT ON THE INDIVIDUAL."
  301. 7016  PRINT : PRINT "AT BIRTH THE THREE CYCLES COINCIDE. " CHR$(ZP)"THIS CONDITION IS NOT REPEATED UNTIL 58"
  302. 7017  PRINT "YEARS HAVE ELAPSED.  THE CYCLES ARE " CHR$(ZP)"CONSTANTLY OUT OF PHASE WITH EACH OTHER.": PRINT : IF   NOT PZ  THEN  INPUT "CONTINUE";YN$: HOME 
  303. 7018  PRINT "THREE PRIMARY STATES OCCUR FOR EACH " CHR$(ZP)"CURVE:"
  304. 7019  PRINT : PRINT "**POSITIVE STATE**": PRINT 
  305. 7020  PRINT "WHEN A CURVE IS ABOVE THE CENTERLINE, " CHR$(ZP)"IT IS IN THE POSITIVE STATE.  DURING"
  306. 7021  PRINT "THIS PHASE OF THE CYCLE A RELATIVE " CHR$(ZP)"STRENGTH OF THE CHARACTERISTIC IS"
  307. 7022  PRINT "INDICATED.  THIS REPRESENTS 'GOOD' " CHR$(ZP)"DAYS EMOTIONALLY, PHYSICALLY, OR INTEL-"
  308. 7023  PRINT "LECTUALLY DEPENDING UPON WHICH CURVES " CHR$(ZP)"ARE ABOVE CENTERLINE."
  309. 7024  PRINT : PRINT "**NEGATIVE STATE": PRINT 
  310. 7025  PRINT "WHEN THE CURVES FALL BENEATH THE " CHR$(ZP)"CENTERLINE, THEY ARE IN THE NEGATIVE"
  311. 7026  PRINT "STATE.  CHARACTERISTICS OCCURRING " CHR$(ZP)"DURING THIS PHASE OF THE CYCLE REPRE-"
  312. 7027  PRINT "SENT PERIODS WHEN ONE IS NOT AT ONE'S " CHR$(ZP)"PEAK RELATIVE TO EITHER THE EMOTIONAL,"
  313. 7028  PRINT "PHYSICAL, OR INTELLECTUAL ABILITIES.": IF   NOT PZ  THEN  INPUT "CONTINUE";YN$: HOME 
  314. 7029  PRINT : PRINT "**CRITICAL DAYS**": PRINT 
  315. 7030  PRINT "THE THIRD AND MOST IMPORTANT ELEMENT " CHR$(ZP)"OF THE CYCLE LASTS FOR ONLY ONE DAY."
  316. 7031  PRINT "THIS IS CALLED THE 'CRITICAL' DAY.  " CHR$(ZP)"IT OCCURS WHEN THE CURVE CROSSES THE"
  317. 7032  PRINT "CENTERLINE FROM POSITIVE-TO-NEGATIVE " CHR$(ZP)"OR FROM NEGATIVE-TO-POSITIVE."
  318. 7033  PRINT : PRINT "IT IS DURING THESE CRITICAL DAYS THAT " CHR$(ZP)"ONE'S ABILITIES TO COPE WITH DIFFICULT"
  319. 7034  PRINT "SITUATIONS ARE STRAINED.  THE CRITICAL " CHR$(ZP)"DAYS ARE REFERRED TO AS PERIODS OF IN-"
  320. 7035  PRINT "STABILITY.  IT HAS BEEN STATISTICALLY " CHR$(ZP)"DEMONSTRATED THAT 70-90% OF ALL ACCI-"
  321. 7036  PRINT "DENTS CAUSED BY HUMAN ERROR OCCUR WHEN " CHR$(ZP)"THE PERSON CAUSING THE ACCIDENT IS"
  322. 7037  PRINT "HAVING A CRITICAL DAY."
  323. 7038  PRINT : IF   NOT PZ  THEN  INPUT "CONTINUE";YN$: HOME 
  324. 7039  PRINT "ON CRITICAL DAYS ONE SHOULD TRY TO " CHR$(ZP)"AVOID DIFFICULT SITUATIONS AND TAKE IT"
  325. 7040  PRINT "EASY.  CRITICAL DAYS IN THE EMOTIONAL " CHR$(ZP)"AND PHYSICAL CYCLES TEND TO BE MORE"
  326. 7041  PRINT "PRONOUNCED THAN THE CRITICAL DAYS IN " CHR$(ZP)"THE INTELLECTUAL CYCLE.  BIORHYTHM"
  327. 7042  PRINT "CHARTS PROMOTE UNDERSTANDING OF THE " CHR$(ZP)"BEHAVIOR OF OTHERS AS WELL AS ONESELF."
  328. 7200  IF PZ  THEN  PRINT  CHR$(19): PRINT  CHR$(4)"PR#0"
  329. 7205  IF   NOT PZ  THEN  PRINT : INPUT "CONTINUE";YN$
  330. 7207  HOME 
  331. 7210  RETURN 
  332. 10000  DATA   5: REM   NUMBER OF NAMES
  333. 10010  DATA  "STEVE","3/13/43"
  334. 10020  DATA  "PAT","3/20/36"
  335. 10030  DATA  "SUSAN","11/20/69"
  336. 10040  DATA  "JERRY","8/4/62"
  337. 10050  DATA  "FRANK","12/22/61"
  338. 11000  DATA  "JANUARY","FEBRUARY","MARCH","APRIL","MAY","JUNE","JULY","AUGUST","SEPTEMBER","OCTOBER","NOVEMBER","DECEMBER"
  339. 11010  DATA  31,28,31,30,31,30,31,31,30,31,30,31